Notificación

TUTORIAL

Quitar la Notificación de Actualización a Windows  X

DESCRIPCIÓN

Microsoft pone a disposición de los usuarios Windows 10 de forma gratuita durante un año desde la fecha de disponibilidad.

Esta oferta está disponible para los clientes que usan ediciones de Windows 7 y Windows 8.1 que no sean Enterprise o Embedded.

Si tiene Windows 7 Pro o Windows 8.1 Pro implementado en su organización, se le presentará la oferta de Windows 10.

En este artículo se describen las opciones de notificación y actualización, y se explica cómo administrarlas.

Con independencia de los actuales criterios excluyentes, los administradores que deseen impedir la actualización Windows 7, Windows 7 for Embedded Systems, Windows 8.1 y Windows Embedded 8.1 Pro deben habilitar la configuración de directivas que se describe en este artículo.

. : Cómo administrar la actualización de Windows 10 : .

Quitar la Notificación de Windows 10

Este Script permite ocultar, eliminar o desinstalar la Notificación de Windows 10 (GWX).

Para ello, siga estos pasos:

1º . Copiar el siguiente código...

2º. Inicie el Bloc de notas, pegue el código y guarde el documento con nombre:

RemoveGWX.cmd

3º. Ejecute el archivo con privilegios de Administrador, y siga las instrucciones.

::==================================================================================
:: NOMBRE     : Quitar la Notificación de Windows 10.
:: AUTOR     : Uinglond.
:: VERSIÓN     : 3.0.
::==================================================================================


:: Configurando la pantalla de CMD.
:: /************************************************************************************/
echo off
title Quitar la notificaci¢n de Windows 10.
color 17
cls
:: /************************************************************************************/


:: Verificando los permisos de administrador.
:: /************************************************************************************/
openfiles>nul 2>&1

if %errorlevel%==0 goto Variables

cls
ver
echo Herramienta para quitar la notificaci¢n de Windows 10.
echo.
echo Es necesario ejecutar esta herramienta con permisos de administrador.
echo.
echo Presione una tecla para continuar . . . 
pause>nul
goto Salir
:: /************************************************************************************/


:: Creando variables temporales.
:: /************************************************************************************/
:Variables

set version=0.0.0000
set nombre=Windows
set admite=0

for /f "tokens=4-5 delims=[] " %%a in ('ver') do set version=%%a %%b

for %%a in (%version%) do set version=%%a

if %version%==5.0.2195 set nombre=Windows 2000 Professional
if %version%==5.1.2600 set nombre=Windows XP
if %version%==5.2.3790 set nombre=Windows XP Professional x64 Edition
if %version%==6.0.6000 set nombre=Windows Vista
if %version%==6.0.6001 set nombre=Windows Vista SP1
if %version%==6.0.6002 set nombre=Windows Vista SP2
if %version%==6.1.7600 set nombre=Windows 7
if %version%==6.1.7601 set nombre=Windows 7 SP1
if %version%==6.2.9200 set nombre=Windows 8
if %version%==6.3.9200 set nombre=Windows 8.1
if %version%==6.3.9600 set nombre=Windows 8.1 Update 1
if %version%==10.0.10240 set nombre=Windows 10

if %version%==6.1.7601 set admite=1
if %version%==6.3.9600 set admite=1

cls
echo.
echo Herramienta para quitar la notificaci¢n de Windows 10.
echo.
echo Microsoft %nombre% detectado...
echo.

if %admite%==0 echo Su sistema operativo no es compatible con esta herramienta.
if %admite%==1 goto Terminos

echo.
echo     Se produjo un error al verificar su sistema operativo.
echo     Puede que est‚ utilizando una versi¢n empresarial o de prueba.
echo     De no ser as¡, verifique el sistema tenga el parche de seguridad
echo     correcto.
echo.
echo     La oferta de actualizaci¢n a Windows 10 es valida para Windows 7 SP1
echo     y Windows 8.1 Update 1.
echo.
echo Presione una tecla para continuar . . . 
pause>nul
goto Salir
:: /************************************************************************************/


:: Escribiendo los términos para el uso de la herramienta.
:: /************************************************************************************/
:Terminos

cls
echo.
echo Microsoft %nombre% [Versi¢n: %version%]
echo Herramienta para quitar la notificaci¢n de Windows 10.
echo.
echo     Los procedimientos dentro de este ejecutable pueden modificar archivos y 
echo     la configuraci¢n del Registro de Windows.
echo     No se asume ninguna responsabilidad por el uso de este archivo ejecutable.
echo     Este ejecutable se proporciona sin ning£n tipo de garant¡a. Cualquier da¤o 
echo     causado es bajo su propia responsabilidad.
echo.
echo     Los archivos .bat son casi siempre marcados por el anti-virus, no dude en
echo     revisar el c¢digo si no est  seguro.
echo.

choice /c SN /n /m "¨Desea continuar con este proceso? (S¡/No) "
if %errorlevel%==1 goto Menu
if %errorlevel%==2 goto Salir

echo.
echo Error inesperado.
echo.
echo Presione una tecla para continuar . . . 
pause>nul
goto Salir
:: /************************************************************************************/


:: Creando el menú de acceso a la herramienta.
:: /************************************************************************************/
:Menu

cls
echo.
echo Microsoft %nombre% [Versi¢n: %version%]
echo Herramienta para quitar la notificaci¢n de Windows 10.
echo.
echo      1. Crear una copia de seguridad del registro.
echo      2. Ocultar la notificaci¢n de Windows 10.
echo      3. Eliminar la notificaci¢n de Windows 10.
echo      4. Desinstalar la notificaci¢n de Windows 10.
echo      5. Cerrar.
echo.

set /p Opcion=  Seleccione una opci¢n: 
if %Opcion%==1 goto Registro
if %Opcion%==2 goto Ocultar
if %Opcion%==3 goto Eliminar
if %Opcion%==4 goto Desinstalar
if %Opcion%==5 goto Salir

echo.
echo Opci¢n no valida.
echo.
echo Presione una tecla para continuar . . . 
pause>nul
goto Menu
:: /************************************************************************************/


:: Creando una copia de seguridad del registro de Windows.
:: /*************************************************************************************/
:Registro

for /f "tokens=1-5 delims=/, " %%a in ("%date%") do (
    set fecha=%%a%%b%%c%%d%time:~0,2%%time:~3,2%
)

:: --------------------------------------------------
:: Se crea una copia de seguridad del registro.
cls
echo.
echo Microsoft %nombre% [Versi¢n: %version%]
echo Herramienta para quitar la notificaci¢n de Windows 10.
echo.
echo Creando una copia del registro en: %USERPROFILE%\Desktop\Backup%fecha%.reg
echo.

if exist "%USERPROFILE%\Desktop\Backup%fecha%.reg" (
    echo Error inesperado.
    echo.
    echo     No se realizaron cambios en el registro.
    echo     Int‚ntalo m s tarde.
    echo.
    echo Presione una tecla para continuar . . . 
    pause>nul
    goto Menu
) else (
    regedit /e "%USERPROFILE%\Desktop\Backup%fecha%.reg"
)
:: --------------------------------------------------

:: --------------------------------------------------
:: Se verifica que se ha creado la copia del registro.
cls
echo.
echo Microsoft %nombre% [Versi¢n: %version%]
echo Herramienta para quitar la notificaci¢n de Windows 10.
echo.
echo Verificando la copia de seguridad.
echo.

if not exist "%USERPROFILE%\Desktop\Backup%fecha%.reg" (
    echo Error inesperado.
    echo.
    echo     Algo sali¢ mal.
    echo     Crea manualmente una copia de seguridad del registro antes de continuar.
    echo.
    echo Presione una tecla para continuar . . . 
    pause>nul
    goto Menu
) else (
    echo La operaci¢n se complet¢ correctamente.
    echo.
    echo Presione una tecla para continuar . . . 
    pause>nul
    goto Menu
)
:: --------------------------------------------------

:: /*************************************************************************************/


:: Ocultando la notificación de Windows 10 a través del Registro de Windows.
:: /************************************************************************************/
:Ocultar

cls
echo.
echo Microsoft %nombre% [Versi¢n: %version%]
echo Herramienta para quitar la notificaci¢n de Windows 10.
echo.
echo Se van a agregar nuevos valores al registro.
echo.

reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\GWX" /v DisableGWX /t REG_DWORD /d 1 /f

reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate" /v DisableOSUpgrade /t REG_DWORD /d 1 /f

reg add "HKLM\Software\Microsoft\Windows\CurrentVersion\WindowsUpdate\OSUpgrade" /v AllowOSUpgrade /t REG_DWORD /d 0 /f
reg add "HKLM\Software\Microsoft\Windows\CurrentVersion\WindowsUpdate\OSUpgrade" /v ReservationsAllowed /t REG_DWORD /d 0 /f

goto Menu
:: /************************************************************************************/


:: Eliminando la aplicación de notificación de Windows 10.
:: /************************************************************************************/
:Eliminar

:: --------------------------------------------------
:: Se detiene el proceso de "Get Windows 10".
cls
echo.
echo Microsoft %nombre% [Versi¢n: %version%]
echo Herramienta para quitar la notificaci¢n de Windows 10.
echo.
echo Cerrando la notificaci¢n de Windows 10.
echo.

taskkill /f /im GWX.exe /t
:: --------------------------------------------------

:: --------------------------------------------------
:: Se eliminan las tareas de "Get Windows 10".
cls
echo.
echo Microsoft %nombre% [Versi¢n: %version%]
echo Herramienta para quitar la notificaci¢n de Windows 10.
echo.
echo Quitando las tareas programadas de la notificaci¢n de Windows 10.
echo.

takeown /r /f "%SYSTEMROOT%\System32\Tasks\Microsoft\Windows\Setup\gwx"

takeown /r /f "%SYSTEMROOT%\System32\Tasks\Microsoft\Windows\Setup\GWXTriggers"

icacls "%SYSTEMROOT%\System32\Tasks\Microsoft\Windows\Setup\gwx\launchtrayprocess" /grant Administrador:F
icacls "%SYSTEMROOT%\System32\Tasks\Microsoft\Windows\Setup\gwx\launchtrayprocess" /grant Administradores:F
icacls "%SYSTEMROOT%\System32\Tasks\Microsoft\Windows\Setup\gwx\refreshgwxconfig" /grant Administrador:F
icacls "%SYSTEMROOT%\System32\Tasks\Microsoft\Windows\Setup\gwx\refreshgwxconfig" /grant Administradores:F
icacls "%SYSTEMROOT%\System32\Tasks\Microsoft\Windows\Setup\gwx\refreshgwxconfigandcontent" /grant Administrador:F
icacls "%SYSTEMROOT%\System32\Tasks\Microsoft\Windows\Setup\gwx\refreshgwxconfigandcontent" /grant Administradores:F

icacls "%SYSTEMROOT%\System32\Tasks\Microsoft\Windows\Setup\GWXTriggers\Logon-5d" /grant Administrador:F
icacls "%SYSTEMROOT%\System32\Tasks\Microsoft\Windows\Setup\GWXTriggers\Logon-5d" /grant Administradores:F
icacls "%SYSTEMROOT%\System32\Tasks\Microsoft\Windows\Setup\GWXTriggers\MachineUnlock-5d" /grant Administrador:F
icacls "%SYSTEMROOT%\System32\Tasks\Microsoft\Windows\Setup\GWXTriggers\MachineUnlock-5d" /grant Administradores:F
icacls "%SYSTEMROOT%\System32\Tasks\Microsoft\Windows\Setup\GWXTriggers\OutOfIdle-5d" /grant Administrador:F
icacls "%SYSTEMROOT%\System32\Tasks\Microsoft\Windows\Setup\GWXTriggers\OutOfIdle-5d" /grant Administradores:F
icacls "%SYSTEMROOT%\System32\Tasks\Microsoft\Windows\Setup\GWXTriggers\OutOfSleep-5d" /grant Administrador:F
icacls "%SYSTEMROOT%\System32\Tasks\Microsoft\Windows\Setup\GWXTriggers\OutOfSleep-5d" /grant Administradores:F
icacls "%SYSTEMROOT%\System32\Tasks\Microsoft\Windows\Setup\GWXTriggers\refreshgwxconfig-B" /grant Administrador:F
icacls "%SYSTEMROOT%\System32\Tasks\Microsoft\Windows\Setup\GWXTriggers\refreshgwxconfig-B" /grant Administradores:F
icacls "%SYSTEMROOT%\System32\Tasks\Microsoft\Windows\Setup\GWXTriggers\Time-5d" /grant Administrador:F
icacls "%SYSTEMROOT%\System32\Tasks\Microsoft\Windows\Setup\GWXTriggers\Time-5d" /grant Administradores:F
icacls "%SYSTEMROOT%\System32\Tasks\Microsoft\Windows\Setup\GWXTriggers\Telemetry-4xd" /grant Administrador:F
icacls "%SYSTEMROOT%\System32\Tasks\Microsoft\Windows\Setup\GWXTriggers\Telemetry-4xd" /grant Administradores:F

schtasks.exe /delete /tn "\Microsoft\Windows\Setup\gwx\launchtrayprocess" /f
schtasks.exe /delete /tn "\Microsoft\Windows\Setup\gwx\refreshgwxconfig" /f
schtasks.exe /delete /tn "\Microsoft\Windows\Setup\gwx\refreshgwxconfigandcontent" /f

schtasks.exe /delete /tn "\Microsoft\Windows\Setup\GWXTriggers\Logon" /f
schtasks.exe /delete /tn "\Microsoft\Windows\Setup\GWXTriggers\Logon-5d" /f
schtasks.exe /delete /tn "\Microsoft\Windows\Setup\GWXTriggers\MachineUnlock-5d" /f
schtasks.exe /delete /tn "\Microsoft\Windows\Setup\GWXTriggers\OutOfIdle" /f
schtasks.exe /delete /tn "\Microsoft\Windows\Setup\GWXTriggers\OutOfIdle-5d" /f
schtasks.exe /delete /tn "\Microsoft\Windows\Setup\GWXTriggers\OutOfSleep-5d" /f
schtasks.exe /delete /tn "\Microsoft\Windows\Setup\GWXTriggers\refreshgwxconfig-B" /f
schtasks.exe /delete /tn "\Microsoft\Windows\Setup\GWXTriggers\Time-5d" /f
schtasks.exe /delete /tn "\Microsoft\Windows\Setup\GWXTriggers\Telemetry-4xd" /f
:: --------------------------------------------------

:: --------------------------------------------------
:: Se renombra la carpeta de "Get Windows 10".
cls
echo.
echo Microsoft %nombre% [Versi¢n: %version%]
echo Herramienta para quitar la notificaci¢n de Windows 10.
echo.
echo Eliminando las carpetas de la notificaci¢n de Windows 10.
echo.

if exist "%SYSTEMROOT%\System32\GWX" (
    takeown /r /f "%SYSTEMROOT%\System32\GWX"
    
    icacls "%SYSTEMROOT%\System32\GWX" /grant Administrador:F
    icacls "%SYSTEMROOT%\System32\GWX" /grant Administradores:F
    
    cd /d "%SYSTEMROOT%\System32\GWX"
    del /s /q /f *.*
    
    cd /d "%SYSTEMROOT%\System32"
    rmdir /s /q "%SYSTEMROOT%\System32\GWX"
)

if exist "%SYSTEMROOT%\SysWOW64\GWX" (
    takeown /r /f "%SYSTEMROOT%\SysWOW64\GWX"
    
    icacls "%SYSTEMROOT%\SysWOW64\GWX" /grant Administrador:F
    icacls "%SYSTEMROOT%\SysWOW64\GWX" /grant Administradores:F
    
    cd /d "%SYSTEMROOT%\SysWOW64\GWX"
    del /s /q /f *.*
    
    cd /d "%SYSTEMROOT%\SysWOW64"
    rmdir /s /q "%SYSTEMROOT%\SysWOW64\GWX"
)
:: --------------------------------------------------

:: --------------------------------------------------
:: Se finaliza el proceso.
cls
echo.
echo Microsoft %nombre% [Versi¢n: %version%]
echo Herramienta de activaci¢n de componentes de Windows Update.
echo.
echo La operaci¢n se complet¢ correctamente.
echo.
echo Presione una tecla para continuar . . . 
pause>nul
goto Menu
:: --------------------------------------------------

:: /************************************************************************************/


:: Desinstalando la actualización de la notificación de Windows 10.
:: /************************************************************************************/
:Desinstalar

cls
echo.
echo Microsoft %nombre% [Versi¢n: %version%]
echo Herramienta para quitar la notificaci¢n de Windows 10.
echo.
echo Se va a desinstalar la actualizaci¢n KB3035583.
echo.

wusa.exe /uninstall /kb:3035583

goto Menu
:: /************************************************************************************/


:: Finalizando la herramienta.
:: /*************************************************************************************/
:Salir

exit
:: /*************************************************************************************/

CAPTURAS

WEB DEL AUTOR

. : www.microsoft.com : .